Rumus ANY() Appsheet

Argumen

beberapa daftar (daftar tipe apa saja)

Nilai Pengembalian

Item pertama dari daftar-beberapa jika daftar dibuat (misalnya, menggunakan LIST () ), atau item arbitrer jika daftar-beberapa adalah daftar yang dihasilkan (misalnya, menggunakan FILTER () atau SELECT () ); atau kosong jika beberapa daftar kosong.

Contoh

ANY(Students[Name]): Nilai acak dari kolom Nama pada tabel Siswa . Sewenang-wenang karena urutan nilai dalam daftar kolom [Nama] Siswa tidak dijamin kecuali dibungkus dalam SORT () . Setara dengan ANY(SELECT(Students[Name], TRUE)). Lihat juga SELECT () .

ANY(LIST(1, 2, 3))mengembalikan Nomor : 1

ANY({"Red", "Yellow", "Green"})kembali Teks : Merah

Nilai Kolom

Nilai kolom tunggal dari serangkaian baris mana pun: ANY(SELECT(Products[Price], ([Color] = "Orange")))

1. SELECT(Products[Price], ...)mengembalikan nilai dalam kolom Harga dari baris di tabel Produk yang cocok dengan kriteria pemilihan.
2. [Color] = "Orange"membatasi pemilihan hanya baris-baris dengan nilai kolom Warna persis Oranye .
3. ANY(...) mengembalikan satu nilai sewenang-wenang dari daftar nilai kolom.

Setara dengan: LOOKUP("Orange", "Products", "Color", "Price")

Nilai Tertinggi di Kolom

Harga produk tertinggi: ANY(TOP(SORT(Products[Price], TRUE), 1))

1. Products[Price]mengambil daftar semua nilai dari kolom Harga pada tabel Produk .
2. SORT(..., TRUE)memesan daftar harga secara numerik dalam urutan menurun / tinggi-ke-rendah ( TRUE).
3. TOP(..., 1) menghapus semua kecuali harga pertama dalam daftar yang diurutkan.
4. ANY(...) mengembalikan satu harga yang tersisa dari daftar teratas.

Setara dengan MAX(Products[Price]).

Nilai Pilihan

Nomor telepon seluler, kantor, atau rumah yang dipilih dari yang tidak kosong: ANY(TOP((LIST([Mobile Phone], [Office Phone], [Home Phone]) - LIST("")), 1))

1. LIST([Mobile Phone], [Office Phone], [Home Phone]) menyusun daftar tiga angka.
2. LIST(...) - LIST("") menghapus semua item kosong dari daftar angka.
3. TOP(..., 1) menghapus semua kecuali yang pertama dari daftar nomor yang tidak kosong.
4. ANY(...) hanya mengembalikan nomor tidak kosong yang tersisa dari daftar teratas.

Setara dengan INDEX((LIST([Mobile Phone], [Office Phone], [Home Phone]) - LIST("")), 1).

Baris dengan Nilai Tertinggi di Kolom

Baris siswa dengan IPK tertinggi di kelas Mr Sandwich: ANY(TOP(ORDERBY(FILTER("Students", AND(ISNOTBLANK([Teacher]), ([Teacher] = "Mr Sandwich"))), [GPA], TRUE), 1))

• FILTER("Students", ...)mengembalikan daftar nilai kunci dari tabel Siswa yang sesuai dengan ketentuan.
• AND(..., ...) membatasi filter hanya ke baris yang cocok dengan semua sub-kondisi yang diberikan.
• ISNOTBLANK([Teacher])membutuhkan nilai kolom Guru tidak boleh kosong.
• [Teacher] = "Mr Sandwich"membutuhkan nilai kolom Guru sama persis dengan Mr Sandwich .
• ORDERBY(..., [GPA], TRUE)memesan kunci yang difilter berdasarkan nilai nilai kolom IPK yang sesuai dalam urutan menurun / tinggi ke rendah ( TRUE), dengan menempatkan IPK tinggi lebih dulu.
• TOP(..., 1) menghapus semua kecuali item pertama dalam daftar pesanan, hanya menyisakan kunci dari baris yang memiliki IPK tertinggi.
• ANY(...) mengembalikan satu entri yang tersisa dari daftar teratas: kunci dari baris yang sesuai dengan siswa dengan IPK tertinggi di kelas Mr Sandwich.

Setara dengan MAXROW("Students", "GPA", AND(ISNOTBLANK([Teacher]), ([Teacher] = "Mr Sandwich"))).

Masalah potensial

ANY(1, 2, 3): argumen tidak dalam bentuk daftar. Untuk memperbaiki, membungkus mereka di LIST () untuk membangun daftar: ANY(LIST(1, 2, 3)).